Where have the language-specific communities gone?

Communication
13

Usually, when I have country-specific question, I am simply using native language (french here), and eventually with minimal english introduction. One example could be this French VAT declaration topic.

if you don’t speak french, you should have enough elements to know what it is about, and decide if you want to push the “translate” button or not on the post.

Yes. Here I am using a small awk script to restore proper thread support.

awk script 
BEGIN {
	hasReferences = 0
	topic = 0
	inHeader = 1
}

# Extract topic from Message-ID.
/^Message-ID: / {
	split($2, msgid, "/")
	topic = msgid[2]
}

# Mark if References header was found.
/^References: / {
	hasReferences = 1
}

# End of headers. If no previous References header, add a new one based on
# topic from Message-ID.
/^$/ {
	# only the first /^$/ marks the end of headers.
	if (inHeader == 1) {
		inHeader = 0

		# show References if not already showed and has a valid topic (Message-ID is optional)
		if (hasReferences == 0 && topic != 0) {
			hasReferences = 1
			printf "References: <topic/%d@discuss.tryton.org>", topic
			print
		}
	}
}

# Quote quotation.
/^\[quote=/,/\[\/quote]/ {
	print "> " $0
	next
}

# Remove value-less informations.
/^You are receiving this because you enabled mailing list mode\.$/ { next }
/^To unsubscribe from these emails, / { next }
/https:\/\/discuss\.tryton\.org\/email\/unsubscribe\// { next }

# Set footer correctly for mutt.
/^---$/ {
	print "-- "
	next
}

# Output all lines by default.
{
	print
}
1 Like