# Where have the language-specific communities gone?

**URL:** <https://discuss.tryton.org/t/where-have-the-language-specific-communities-gone/3635>\
**Category:** Communication\
**Created:** [January 4, 2021, 9:14am UTC](https://discuss.tryton.org/t/where-have-the-language-specific-communities-gone/3635 "2021-01-04T09:14:16Z")\
**Posts on this page:** 1\
**Showing post:** 13

<div class="post-metadata">

**Author:** ![semarie](https://discuss-cdn.tryton.org/user_avatar/discuss.tryton.org/semarie/32/112_2.png) [@semarie](https://discuss.tryton.org/u/semarie)\
**Post date:** [January 6, 2021, 4:41pm UTC](https://discuss.tryton.org/t/where-have-the-language-specific-communities-gone/3635/13 "2021-01-06T16:41:27Z")

</div>

> [@htgoebel](#):
>
> But often it is quite a hurdle, if one must first explain the country-specific requirements (which exist) to foreigners. In a language/country-specific group I would expect more user knowing the requirements.

Usually, when I have country-specific question, I am simply using native language (french here), and eventually with minimal english introduction. One example could be this [French VAT declaration](https://discuss.tryton.org/t/french-vat-declaration/1170) topic.

if you don’t speak french, you should have enough elements to know what it is about, and decide if you want to push the “translate” button or not on the post.

> [@yangoon](#):
>
> Email threading is broken

Yes. Here I am using a small awk script to restore proper thread support.

> **awk script**
>
> ```awk
> BEGIN {
> hasReferences = 0
> topic = 0
> inHeader = 1
> }
> 
> # Extract topic from Message-ID.
> /^Message-ID: / {
> split($2, msgid, "/")
> topic = msgid[2]
> }
> 
> # Mark if References header was found.
> /^References: / {
> hasReferences = 1
> }
> 
> # End of headers. If no previous References header, add a new one based on
> # topic from Message-ID.
> /^$/ {
> # only the first /^$/ marks the end of headers.
> if (inHeader == 1) {
> inHeader = 0
> 
> # show References if not already showed and has a valid topic (Message-ID is optional)
> if (hasReferences == 0 && topic != 0) {
> hasReferences = 1
> printf "References: <topic/%d@discuss.tryton.org>", topic
> print
> }
> }
> }
> 
> # Quote quotation.
> /^\[quote=/,/\[\/quote]/ {
> print "> " $0
> next
> }
> 
> # Remove value-less informations.
> /^You are receiving this because you enabled mailing list mode\.$/ { next }
> /^To unsubscribe from these emails, / { next }
> /https:\/\/discuss\.tryton\.org\/email\/unsubscribe\// { next }
> 
> # Set footer correctly for mutt.
> /^---$/ {
> print "-- "
> next
> }
> 
> # Output all lines by default.
> {
> print
> }
> 
> ```

---

_[View the full topic](https://discuss.tryton.org/t/where-have-the-language-specific-communities-gone/3635)._